список подключенных принтеров в lookup на форме

[lexx]

All, помогите получить в lookup на форме список подключенных принтеров.

[maxsmirnov]

см. \Forms\SysPrintForm\methods\buildPrinterComboBox

[lexx]

там список формируется через
sysPrintOptions = SysPrintOptions::construct(object, str2int(args.parm()));
а object потрошится до RunBaseReport и RunBase
а моя форма прямого отношения к отчетам не имеет

тогда как его обмануть с этим object'ом

[maxsmirnov]

обманывайте внаглую

PHP код:

static void Job3(Args _args)
{
    printJobSettings printJobSettings = new printJobSettings(connull(), true);
    SysPrintOptions SysPrintOptions = SysPrintOptions::construct(printJobSettings, 0);
    map map;
    mapIterator mapIterator;

    PrinterName     printerName;
    PrinterName     displayPrinterName;
    ClassRunMode    classRunMode;

    ;
    map = SysPrintOptions.getPrinterMap();

    mapIterator = new MapIterator(map);
    mapIterator.begin();
    while (mapIterator.more())
    {
        [printerName, classRunMode, displayPrinterName] = mapIterator.value();
        
        info(strfmt("%1 - %2", printerName, displayPrinterName));

        mapIterator.next();
    }
} 


[Dron AKA andy]

Список принтеров можно получить через системный класс PrintJobSettings напрямую, без всяких мапов

[lexx]

всем спасибо - заработало

[George Nordic]

PHP код:

static void Job5(Args _args)
{
    printJobSettings printJobSettings = new printJobSettings(connull(), true);
    str             printerName;
    int             numOfPrinters, z;
    ;

    numOfPrinters = printJobSettings.getNumberOfPrinters();
    for (z = 1; z <= numOfPrinters; z++)
    {
        printerName = printJobSettings.getPrinter(z);
        info (printerName);
    }
} 


[DmitryK]

Понадобилось получить список принтеров. Нашел эту тему, очень лаконичное решение!!! Отлично!!!
Но есть одно но. Георгий, если в ax2009 поставить точку останова в этом job, то axapta умирает, причем так, что ее остатки (дебагер) можно снять только через диспетчер задач
Любопытно. Сталкивался ли кто с подобным?

C уважением, Дмитрий

[alvares]

DmitryK, можно делать так и никто не умирает

static void ShowListOfPrinters(Args _args) 
{ 
    printJobSettings        printJobSettings; 
    sysPrintOptions         sysPrintOptions; 
    map                     printerMap; 
    mapIterator             mapIterator; 
    ; 
    printJobSettings = 
SysPrintOptions::newPrintJobSettingsOnServer(); 
    sysPrintOptions = new sysPrintOptions(); 
     
    sysPrintOptions.setPrintJobSettings(printJobSettings); 
     
    sysPrintOptions.buildPrinterMap(); 
    printerMap = sysPrintOptions.getPrinterMap(); 
    mapIterator = new mapIterator(printerMap); 
    mapIterator.begin(); 
    while (mapIterator.more()) 
    { 
        info(mapIterator.value()); 
        mapIterator.next(); 
    } 
}

[DmitryK]

Спасибо, попробуем на прочность
Удивительно, что предыдущий код работает без отладчика

С уважением, Дмитрий