Поиск разных значений. AX 4.0 sp2.

[Alexx7]

Доброе.

Ищу способы реализации задачи:
Имеем список значений (контейнер):
1. 00001
2. 00001
3. 00001
4. 00002
5. 00001

Как определить, что четвертое значение отлично от всех остальных. Или задача минимум - как определить что в контейнере (или любой массив). не все значения одинаковы.

Спасибо.

[ice]

Пробегитесь по нему. вы программист?

[sukhanchik]

Есть еще класс Set, который не допускает хранения неуникальных значений. Можно его задействовать.
А иногда и временную таблицу бывает удобнее использовать. В общем - вопрос не раскрыт

[Alexx7]

Цитата:

Сообщение от ice

Пробегитесь по нему. вы программист?

Да. Но меня посетила только одна идея - если текущее значени ене равно предидущему.

Я просто надеюсь на то, что есть калсс или процедура о которой я не знаю, которая примет котейнер или массив, проверит его по моему условию, а вернет bool-занчение. (Я понимаю, что маловероятно, но вдруг.. В 1С есть такой метод. Думаю, что а AX тоже должен быть.).

[Alexx7]

Цитата:

Сообщение от sukhanchik

Есть еще класс Set, который не допускает хранения неуникальных значений. Можно его задействовать.
А иногда и временную таблицу бывает удобнее использовать. В общем - вопрос не раскрыт

В таблице ProdBOM требуется проверить, чтобы ItemID во всех строках был одинаковый.

[anykey]

можно так, наверное:

void isConRecUnique(Args _args)
{
   Container    myCon;
   Set          mySet = new set(Types::String);
   Int          elementsNum;
   ;
   //... fill in container
   elementsNum = conlen(mycon);
   info(elementsNum == set::create( [ 1, any2int(mySet.typeId()), elementsNum ] + myCon ).elements() ?
        "Unique" : "Not unique") ;
}

[Alexx7]

Цитата:

Сообщение от anykey

можно так, наверное:
.....

Да. Это работает, но в том случае если все значения в списке уникальны (Unique) или хотябы одно повтаряется (Not Unique). А надо наборот в списке не все значения одинаковы - значит ошибка, все одинаковы значит хорошо.

[anykey]

если все одинаковы - в сет добавится только один элемент, т.е.

info(set::create( [ 1, any2int(mySet.[typeId()), elementsNum ] + myCon ).elements() > 1 ?
        "Плохо" : "Хорошо")

[Zabr]

Цитата:

Сообщение от anykey

если все одинаковы - в сет добавится только один элемент, т.е.

info(set::create( [ 1, any2int(mySet.[typeId()), elementsNum ] + myCon ).elements() > 1 ?
        "Плохо" : "Хорошо")

Красиво. Вот еще вариация:

static void CheckItems(Args _args)
{
itemid FirstItem; // itemid первой строки
str    AllItems; // список itemid всех строк
int N; // record count
;

// fill in FirstItem & AllItems ...

info( (AllItems == strrep(FirstItem,N)) ? "Хорошо" : "Плохо");
}

[fed]

Может я не понял задачи, но почему бы обычный запрос к ProdBOM не использовать ?
Типа

select prodBom
where prodBom.prodId==value
exists join prodBom2
where prodBOM2.prodId==prodBom.prodId &&
prodBom2.itemId!=prodBom.itemId
;
if (prodBom)
    throw "Непорядок!";

Ну или так:

select itemId
group by itemId
from prodBOM
where prodBOM.prodId==value;
itemId1=prodBom.itemId;
next prodBom;
if (ProdBom)
    throw StrFmt("Непорядок - есть номенклатуры %1 и %2", itemId1,prodBom.itemId);

Ну то есть - это я к тому, что вытаскивать данные в память и там обрабатывать стоит только тогда, когда эту же задачу в принципе не удается переложить на SQL-сервер

[vallys]

Цитата:

Сообщение от Alexx7

В таблице ProdBOM требуется проверить, чтобы ItemID во всех строках был одинаковый.

А зачем делать лишнюю работу по формированию контейнера/массива? Сразу спросите у sql-сервера, есть ли повторяющиеся ItemID...
Вариантов может быть несколько, например так:

static void TestJob(Args _args)
{
    ProdBOM     prodBOM;
    ProdBOM     prodBOM2;
    ;
    select firstonly ItemId
        from ProdBOM
        where ...;
    select firstonly ItemId
        from prodBOM2
        where ... &&
                 prodBOM2.ItemId != prodBOM.ItemId;
    if (prodBOM2)
        info(strfmt("В таблице ProdBOM встречаются как минимум два значения ItemId: '%1'; '%2'", prodBOM.ItemId, prodBOM2.ItemId));
    else
        info(strfmt("В таблице ProdBOM встречается только одно значение ItemId: '%1'", prodBOM.ItemId));
}

З.Ы. Опоздал
З.Ы.Ы. to fed: select (без while и next) желательно использовать c firstonly

[Alexx7]

Всем спасибо. Воспользовался вариантом Господина anykey.
Всё работает стабильно.

[mazzy]

Цитата:

Сообщение от Alexx7

Всё работает стабильно.

Только в памяти клиента или AOS'а. С генерацией трафика от SQL-сервера.

Послушайте совета fed и vallys - отдайте работу на SQL.

[Zabr]

Цитата:

Сообщение от Alexx7

В таблице ProdBOM требуется проверить, чтобы ItemID во всех строках был одинаковый.

Если в идеологии конкретно вашей системы так должно быть всегда, то возможно вам имеет смысл просто сделать соответствующий уникальный индекс с ItemId для ProdBOM.