как правильно построить фильтр

[S.Kuskov]

Честно говоря, в первый раз слышу про фиктивные условия. Вроде как, если строка условия начинается с открывающейся круглой скобки, то аксапта всегда переключается в режим расширенного синтаксиса и интерпретирует условие "как есть", а не как пользовательский фильтр отдельно взятого поля.

http://www.axaptapedia.com/Expressions_in_query_ranges

Цитата:

To specify the range value itself, certain rules must be followed:

• The entire expression must be enclosed within single-quotes, not double-quotes
• The entire expression must be enclosed in parenthesis (brackets)
• Each sub-expression must be enclosed in its own set of parenthesis
• For fields in the current table, simply the field name can be used
• For fields in other tables, a prefix of the relevant datasource name must be added. This is not always the same as the table name.
• String values should be surrounded by double-quotes, and wrapped in a call to queryValue()
• Enum values should be specified by their integer value
• Date values should be formatted using Date2StrXpp()
• Blank string like ‘ ’ will not work as expected, use sysquery::valueEmptyString().

[timaluhs]

закон Мэрфи опять сработал
почему-то если rangeStart - фильтр по одному полю
rangeStart = qbds.addRange(fieldnum(MyTBL, STARTDATE));
rangeStart.value(strfmt('%1..%2',FromDate.valueStr(),ToDate.valueStr()));
то работает и даты как положено воспринимает

SELECT * FROM MyTBL WHERE ... AND ((StartDate>={ts '2011-01-01 00:00:00.000'} AND StartDate<={ts '2011-05-22 00:00:00.000'})) AND .....

а если
str rangeDate = strfmt("(((STARTDATE>=%1) and (STARTDATE<=%2)) or ((ENDDATE>=%1) and (ENDDATE<=%2)))", FromDate.valueStr(), ToDate.valueStr());
rangeDates = qbds.addRange(fieldNum(MyTBL ,RecId));
rangeDates.value(rangeDate); - фильтр по RecID

то даты имеют вид другой
SELECT * FROM MyTBL WHERE ... AND (((((STARTDATE>=01/01/2011) and (STARTDATE<=22/05/2011)) or ((ENDDATE>=01/01/2011) and (ENDDATE<=22/05/2011)))))
ещё ругается что какой-то скобки не хватает.

[Date values should be formatted using Date2StrXpp() ]

пыталась вместо FromDate.valueStr() - date2strxpp(FromDate) ругается
Argument '_date' ia incompatible with required type.

[S.Kuskov]

Цитата:

Сообщение от timaluhs

[Date values should be formatted using Date2StrXpp() ]

пыталась вместо FromDate.valueStr() - date2strxpp(FromDate) ругается
Argument '_date' ia incompatible with required type.

Аргумент функции date2strxpp должен иметь тип дата. Попробуйте чтото вроде

date2strxpp(FromDate.DateValue())

[timaluhs]

поставила
date2strxpp(FromDate.DateValue())
теперь SQL вообще какой-то кривой

(((((STARTDATE>=01\01\2011) and (STARTDATE<=22\05\2011)) or ((ENDDATE>=01\01\2011) and (ENDDATE<=22\05\2011)))))

[S.Kuskov]

Цитата:

Сообщение от timaluhs

теперь SQL вообще какой-то кривой

Что именно вам не нравится? Если вы про пару лишних внешних скобок, то это нормаьлно

Ещё. Вместо AND и OR используйте && и || соответственно.

[timaluhs]

почему && и || ?это же запрос который идёт на SQL сервер. Там вроде как and и or надо.
и слэши обратные как -то не очень. SQL сервер ругается на такое
"Incorrect syntax near '\01'."
не нравится ему дата в таком виде

[S.Kuskov]

Цитата:

Сообщение от timaluhs

это же запрос который идёт на SQL сервер

Неа. Это запрос, который ещё будет постобработан аксаптой.

Вот такой код у меня выполняется без ошибок:

static void JobTestExpressionsInQueryRanges(Args _args)
{
    InventTrans InventTrans;
    fromDate fromDate   = 03\05\2011;
    toDate  toDate      = 04\05\2011;

    Query q;
    QueryBuildDataSource qbdsInventTrans;
    QueryRun qr;
    ;
    q = new Query();
    qbdsInventTrans = q.addDataSource(tableNum(InventTrans));
    qbdsInventTrans.addRange(fieldNum(InventTrans, RecId)).value(
        strfmt("(((%1.%2 >= %4) && (%1.%2 <= %5)) || ((%1.%3 >= %4) && (%1.%3 <= %5)))" ,
            qbdsInventTrans.name(),
            fieldStr(InventTrans, DatePhysical),
            fieldStr(InventTrans, DateFinancial),
            Date2StrXpp(fromDate),
            Date2StrXpp(toDate)
        ));

    info(qbdsInventTrans.toString());

    qr = new QueryRun(q);
    while (qr.next())
    {
        InventTrans = qr.get(tableNum(InventTrans));
        info(InventTrans.ItemId);
        break;
    }

    info(".");
}

Обратите внимание на то, что имя таблицы, а точнее имя источника данных, в данном запросе (в условии участвует поля из одной и той же таблицы) можно было не указывать, но в общем случае его указывать нужно.
Впрочем этот нюанс и многие другие описаны в статье по ссылке, которую я приводил выше

[nix0root]

К примеру.

            qbrEmployDate.value(   '(EmplTable.PayEmploymentDate_RU != '+date2StrXpp(datenull())+')'
                                  +'&&'
                                  +'(EmplTable.PayEmploymentDate_RU <= '+date2StrXpp(systemdateget())+')'
                               );
            qbrResignDate.value(   '(EmplTable.PayResignedDate_RU !='+date2StrXpp(datenull())+')'
                                  +'&&'
                                  +'(EmplTable.PayResignedDate_RU < '+date2StrXpp(systemdateget())+')');